Excelファイルの更新をメールで通知する方法【業務自動化】

ファイルを複数人で共有している時など、更新時にメンバーへ連絡することがルール化されている場合があります。

毎回、口頭や手動でメールで連絡していると、連絡漏れや連絡が遅れることが発生する可能性があります。

この記事では、VBAでメール送信機能を作成し、メール通知を自動化する方法を記載します。

メール通知の自動化は、Excel以外にもWordやAccessなどVBAが使えるOfficeソフトであれば、汎用的に使用できますので、業務の効率化を図ることができます。

Outlookの設定

メール送信機能は、VBAからMicrosoft Outlookの機能を使ってメールを送信します。

事前にMicrosoft Outlookにアカウント設定がされていること、メールが送受信ができることを確認してください。

すでにMicrosoft Outlookを使われている方は、再設定する必要はありません。

サンプルファイル

メール送信機能を実装したサンプルファイルをリンクしますので、ご自由にお使いください。

設定シートの項目にメールアドレスなどを入力することでメール通知を行うことができます。

sample.xlsm

1 ファイル 34.28 KB

ダウンロード

参照設定の追加

ここからは、メール送信機能を自身で作成する方法を記載します。

VBAからMicrosoft Outlookの機能を使用するために「Microsoft Outlook 16.0 Object Library」の参照設定を追加します。

メール送信機能コード

VBAのコードを記載します。

Option Explicit

'設定シート情報
Private Const SETTING_SHEET_NAME As String = "設定シート"
Private Const RANGE_TO As String = "B3"
Private Const RANGE_CC As String = "B4"
Private Const RANGE_BCC As String = "B5"
Private Const RANGE_SUBJECT As String = "B6"
Private Const RANGE_BODY As String = "B7"

'送信ボタン押下時の処理
Public Sub SendBtnClicck()
    Dim wsSetting As Worksheet
    Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME)
    
    If wsSetting.OLEObjects("OptBtnSend").Object.Value Then
        Call SendEmail
    End If
    
End Sub

'ファイル保存時の処理
Private Sub Workbook_AfterSave(ByVal Success As Boolean)
    Dim wsSetting As Worksheet
    Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME)
    
    If wsSetting.OLEObjects("OptBtnSave").Object.Value Then
        Call SendEmail
    End If
    
End Sub


'メール送信の処理
Private Sub SendEmail()
On Error GoTo ErrorHandler

    Dim objOutlook As Outlook.Application
    Dim objMail As Outlook.MailItem
    Dim wsSetting As Worksheet

    Set objOutlook = New Outlook.Application
    Set objMail = objOutlook.CreateItem(olMailItem)
    Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME)

    '設定シートの値を設定する
    With wsSetting
        objMail.TO = .Range(RANGE_TO).Value             'TO
        objMail.CC = .Range(RANGE_CC).Value             'CC
        objMail.BCC = .Range(RANGE_BCC).Value           'BCC
        objMail.Subject = .Range(RANGE_SUBJECT).Value   '件名
        objMail.Body = .Range(RANGE_BODY).Value         '本文
        'メールの形式
        If wsSetting.OLEObjects("OptBtnHTML").Object.Value Then
            objMail.BodyFormat = olFormatHTML
        End If
        If wsSetting.OLEObjects("OptBtnPlain").Object.Value Then
            objMail.BodyFormat = olFormatPlain
        End If
    End With
    
    'メール送信
    objMail.Send

    GoTo Finally

ErrorHandler:
    MsgBox "メールの送信に失敗しました", vbOKOnly + vbCritical


Finally:
    Set objOutlook = Nothing

End Sub